Подключиться
Сценарии использования

Начало работы с Terraform

Статья создана
,
улучшена

Terraform позволяет быстро создать облачную инфраструктуру в Yandex.Cloud и управлять ей с помощью файлов конфигураций. В файлах конфигураций хранится описание инфраструктуры на языке HCL (HashiCorp Configuration Language).

При изменении файлов конфигураций Terraform автоматически определяет, какая часть вашей конфигурации уже развернута, что следует добавить или удалить.

Чтобы создать первую конфигурацию Terraform:

  1. Установите Terraform
  2. Создайте файл конфигурации Terraform
  3. Настройте провайдер
  4. Подготовьте план инфраструктуры
  5. Проверьте и отформатируйте файлы конфигурации
  6. Создайте ресурсы
  7. Удалите ресурсы

Подготовьте облако к работе

Перед тем, как разворачивать инфраструктуру, зарегистрируйтесь в Yandex.Cloud и создайте платежный аккаунт:

  1. Перейдите в консоль управления, затем войдите в Yandex.Cloud или зарегистрируйтесь, если вы еще не зарегистрированы.
  2. На странице биллинга убедитесь, что у вас подключен платежный аккаунт, и он находится в статусе ACTIVE или TRIAL_ACTIVE. Если платежного аккаунта нет, создайте его.

Если у вас есть активный платежный аккаунт, вы можете создать или выбрать каталог, в котором будет работать ваша виртуальная машина, на странице облака.

Подробнее об облаках и каталогах.

В стоимость поддержки созданных с помощью Terraform ресурсов входят:

Установите Terraform

Используйте один из способов:

Скачайте дистрибутив Terraform и установите его согласно инструкции.

Используйте один из способов:

Создайте файл конфигурации Terraform

  1. Создайте новую директорию с произвольным названием, например yandex-cloud-terraform. В ней будут храниться конфигурационные файлы и сохраненные состояния Terraform и инфраструктуры.

    Важно

    Каждая конфигурация должна находиться в отдельной директории.

  2. Создайте в новой директории конфигурационный файл с расширением .tf, например main.tf.

Настройте провайдер

  1. В начале конфигурационного файла необходимо задать настройки провайдера.

    Примечание

    Настройки применимы для Terraform 0.13 и более поздних версий.

    terraform {
  required_providers {
    yandex = {
      source  = "yandex-cloud/yandex"
      version = "0.61.0"
    }
  }
}

provider "yandex" {
  token     = "<OAuth>"
  cloud_id  = "<идентификатор облака>"
  folder_id = "<идентификатор каталога>"
  zone      = "<зона доступности по умолчанию>"
}
    • source — глобальный адрес источника провайдера.
    • version — минимальная версия провайдера, с которой совместим модуль. Номер версии можно посмотреть на странице провайдера (кнопка USE PROVIDER в верхнем правом углу).
    • provider — название провайдера.
    • token — OAuth-токен для доступа к Yandex.Cloud.
    • cloud_id — идентификатор облака, в котором Terraform создаст ресурсы.
    • folder_id — идентификатор каталога, в котором по умолчанию будут создаваться ресурсы.
    • zone — зона доступности, в которой по умолчанию будут создаваться все облачные ресурсы.

  2. Выполните команду terraform init в папке с конфигурационным файлом. Эта команда инициализирует провайдеров, указанных в конфигурационных файлах, и позволяет работать с ресурсами и источниками данных провайдера.

Подготовьте план инфраструктуры

С помощью Terraform в Yandex.Cloud можно создавать облачные ресурсы всех типов: виртуальные машины, диски, образы и т.д. Подробную информацию о ресурсах, создающихся с помощью Terraform, см. в документации провайдера.

Для создания ресурса необходимо указать набор обязательных и опциональных параметров, определяющих свойства ресурса. Такие описания ресурсов составляют план инфраструктуры.

По плану будут созданы две виртуальные машины: terraform1 и terraform2, а также облачная сеть network-1 с подсетью subnet-1.

Имена ресурсов должны соответствовать следующим требованиям:

  • Длина — от 3 до 63 символов.
  • Может содержать строчные буквы латинского алфавита, цифры и дефисы.
  • Первый символ — буква. Последний символ — не дефис.

У машин будут разные количества ядер и объемы памяти: 2 ядра и 2 Гб оперативной памяти у terraform1 и 4 ядра и 4 Гб оперативной памяти у terraform2. Машины автоматически получат публичные IP-адреса и приватные IP-адреса из диапазона 192.168.10.0/24 в подсети subnet-1, находящейся в зоне доступности ru-central1-a и принадлежащей облачной сети network-1. На виртуальных машинах будет установлена операционная система Ubuntu и размещена публичная часть ключа для доступа к машинам по SSH.

В конфигурации виртуальной машины вам потребуется указать идентификатор образа загрузочного диска. Список доступных публичных образов можно получить командой CLI yc compute image list --folder-id standard-images.

Для доступа к ВМ через SSH нужно сгенерировать пару SSH-ключей и передать публичную часть ключа на виртуальную машину в параметре ssh-keys блока metadata.

Конфигурации ресурсов задаются сразу после конфигурации провайдера:

terraform {
  required_providers {
    yandex = {
      source = "yandex-cloud/yandex"
    }
  }
}

provider "yandex" {
  token     = "OAuth_token"
  cloud_id  = "cloud-id"
  folder_id = "folder-id"
  zone      = "ru-central1-a"
}

resource "yandex_compute_instance" "vm-1" {
  name = "terraform1"
}

По плану будут созданы следующие ресурсы:

  • Облачная сеть network-1 с подсетью subnet-1 в зоне доступности ru-central1-a.
  • Две виртуальные машины Linux: terraform1 (2 ядра и 2 Гб оперативной памяти) и terraform2 (4 ядра и 4 Гб оперативной памяти). Они автоматически получат публичные и приватные IP-адреса из диапазона 192.168.10.0/24 в подсети subnet-1.

  1. Получите идентификатор образа загрузочного диска, например Ubuntu 16 LTS, который будет установлен на ВМ. Получите список доступных публичных образов, выполнив следующую команду CLI:

    yc compute image list --folder-id standard-images

  2. Сгенерируйте пару SSH-ключей для доступа к ВМ по SSH.

  3. Опишите параметры ресурсов в файле main.tf:

    • В параметре ssh-keys блока metadata укажите путь к публичной части SSH ключа.
    • В image_id задайте идентификатор образа загрузочного диска.
    Файл main.tf 
    <настройки провайдера>

resource "yandex_compute_instance" "vm-1" {
  name = "terraform1"

  resources {
    cores  = 2
    memory = 2
  }

  boot_disk {
    initialize_params {
      image_id = "fd87va5cc00gaq2f5qfb"
    }
  }

  network_interface {
    subnet_id = yandex_vpc_subnet.subnet-1.id
    nat       = true
  }

  metadata = {
    ssh-keys = "ubuntu:${file("~/.ssh/id_rsa.pub")}"
  }
}

resource "yandex_compute_instance" "vm-2" {
  name = "terraform2"

  resources {
    cores  = 4
    memory = 4
  }

  boot_disk {
    initialize_params {
      image_id = "fd87va5cc00gaq2f5qfb"
    }
  }

  network_interface {
    subnet_id = yandex_vpc_subnet.subnet-1.id
    nat       = true
  }

  metadata = {
    ssh-keys = "ubuntu:${file("~/.ssh/id_rsa.pub")}"
  }
}

resource "yandex_vpc_network" "network-1" {
  name = "network1"
}

resource "yandex_vpc_subnet" "subnet-1" {
  name           = "subnet1"
  zone           = "ru-central1-a"
  network_id     = yandex_vpc_network.network-1.id
  v4_cidr_blocks = ["192.168.10.0/24"]
}

output "internal_ip_address_vm_1" {
  value = yandex_compute_instance.vm-1.network_interface.0.ip_address
}

output "internal_ip_address_vm_2" {
  value = yandex_compute_instance.vm-2.network_interface.0.ip_address
}


output "external_ip_address_vm_1" {
  value = yandex_compute_instance.vm-1.network_interface.0.nat_ip_address
}

output "external_ip_address_vm_2" {
  value = yandex_compute_instance.vm-2.network_interface.0.nat_ip_address
}

По плану будут созданы следующие ресурсы:

  • Облачная сеть ya-network с подсетью ya-network в зоне доступности, указанной по умолчанию.
  • Виртуальная машина Windows: terraform1 (2 ядра и 4 Гб оперативной памяти) и terraform2 (4 ядра и 4 Гб оперативной памяти). Она автоматически получит публичные и приватные IP-адреса из диапазона 192.168.10.0/24 в подсети ya-network.

Создайте следующие файлы:

  1. main.tf — основной файл с описанием инфраструктуры.

    Содержимое файла main.tf 
    terraform {
  required_providers {
    yandex = {
      source = "yandex-cloud/yandex"
    }
  }
}

provider "yandex" {
  cloud_id  = var.cloud_id
  folder_id = var.folder_id
  zone      = var.zone
  token     = var.token
}

resource "yandex_vpc_network" "default" {
  name = var.network
}

resource "yandex_vpc_subnet" "default" {
  network_id     = yandex_vpc_network.default.id
  name           = var.subnet
  v4_cidr_blocks = var.subnet_v4_cidr_blocks
  zone           = var.zone
}

data "yandex_compute_image" "default" {
  family = var.image_family
}

data "template_file" "default" {
  template = file("${path.module}/init.ps1")
  vars = {
    user_name  = var.user_name
    user_pass  = var.user_pass
    admin_pass = var.admin_pass
  }
}

resource "yandex_compute_instance" "default" {
  name     = var.name
  hostname = var.name
  zone     = var.zone

  resources {
    cores  = var.cores
    memory = var.memory
  }

  boot_disk {
    initialize_params {
      image_id = data.yandex_compute_image.default.id
      size     = var.disk_size
      type     = var.disk_type
    }
  }

  network_interface {
    subnet_id = yandex_vpc_subnet.default.id
    nat       = var.nat
  }

  metadata = {
    user-data = data.template_file.default.rendered
  }

  timeouts {
    create = var.timeout_create
    delete = var.timeout_delete
  }
}

output "name" {
  value = yandex_compute_instance.default.name
}

output "address" {
  value = yandex_compute_instance.default.network_interface.0.nat_ip_address
}

  2. variables.tf — файл с описанием переменных для создаваемых ресурсов.

    Файл variables.tf 
    variable "cloud_id" {
  type    = string
}

variable "folder_id" {
  type    = string
}

variable "zone" {
  type    = string
  default = "ru-central1-a"
}

variable "token" {
  type    = string
}

variable "network" {
  type    = string
  default = "ya-network"
}

variable "subnet" {
  type    = string
  default = "ya-network"
}

variable "subnet_v4_cidr_blocks" {
  type    = list(string)
  default = ["192.168.10.0/16"]
}

variable "nat" {
  type    = bool
  default = true
}

variable "image_family" {
  type    = string
  default = "windows-2019-dc-gvlk"
}

variable "name" {
  type    = string
}

variable "cores" {
  type    = number
  default = 2
}

variable "memory" {
  type    = number
  default = 4
}

variable "disk_size" {
  type    = number
  default = 50
}

variable "disk_type" {
  type    = string
  default = "network-nvme"
}

variable "user_name" {
  default = ""
  type    = string
}

variable "user_pass" {
  default = ""
  type    = string
}

variable "admin_pass" {
  default = ""
  type    = string
}

variable "timeout_create" {
  default = "10m"
}

variable "timeout_delete" {
  default = "10m"
}

  3. terraform.tfvars — файл, где хранятся значения переменных для создаваемых внутри ВМ учетных записей и токены доступа.

    Файл terraform.tfvars 
    token      = "<token>"
cloud_id   = "<cloud_id>"
folder_id  = "<folder_id>"

name       = "<my_server_name>"
user_name  = "<my_user>"
user_pass  = "<my_password>"
admin_pass = "<my_password>"

Создайте пользователей

Чтобы добавить пользователя на создаваемую ВМ, в блоке metadata укажите параметр user-data с пользовательскими метаданными. Для этого:

  1. Создайте текстовый файл с метаданными, например:

    #cloud-config
users:
  - name: <имя пользователя>
    groups: sudo
    shell: /bin/bash
    sudo: ['ALL=(ALL) NOPASSWD:ALL']
    ssh-authorized-keys:
      - ssh-rsa AAAAB3Nza......OjbSMRX user@example.com
      - ssh-rsa AAAAB3Nza......Pu00jRN user@desktop

  2. В файле main.tf вместо ssh-keys задайте параметр user-data и укажите путь к файлу с метаданными:

    metadata = {
    user-data = "${file("<путь к файлу>/meta.txt")}"
}

Подробнее о работе с метаданными читайте в разделе Метаданные виртуальной машины.

Чтобы создать пользователя и установить пароль учётной записи Administrator на ВМ в Yandex.Cloud можно использовать агент cloudbase-init. Для этого создайте скрипт init.ps1, который будет выполняется агентом при первой загрузке системы. В качестве учетных сведений будут использоваться переменные из файла variables.tf.

Файл init.ps1
#ps1
# ^^^ 'ps1' is only for cloudbase-init, some sort of sha-bang in linux

# logging
Start-Transcript -Path "$ENV:SystemDrive\provision.txt" -IncludeInvocationHeader -Force
"Bootstrap script started" | Write-Host

# inserting value's from terraform
$MyUserName = "${ user_name }"
$MyPlainTextPassword = "${ user_pass }"
if (-not [string]::IsNullOrEmpty($MyUserName) -and -not [string]::IsNullOrEmpty($MyPlainTextPassword)) {
    "Create user" | Write-Host
    $MyPassword = $MyPlainTextPassword | ConvertTo-SecureString -AsPlainText -Force
    $MyUser = New-LocalUser -Name $MyUserName -Password $MyPassword -PasswordNeverExpires -AccountNeverExpires
    $MyUser | Add-LocalGroupMember -Group 'Administrators'
    $MyUser | Add-LocalGroupMember -Group 'Remote Management Users'
}

# inserting value's from terraform
$MyAdministratorPlainTextPassword = "${ admin_pass }"
if (-not [string]::IsNullOrEmpty($MyAdministratorPlainTextPassword)) {
    "Set local administrator password" | Write-Host
    $MyAdministratorPassword = $MyAdministratorPlainTextPassword | ConvertTo-SecureString -AsPlainText -Force
    # S-1-5-21domain-500 is a well-known SID for Administrator
    # https://docs.microsoft.com/en-us/troubleshoot/windows-server/identity/security-identifiers-in-windows
    $MyAdministrator = Get-LocalUser | Where-Object -Property "SID" -like "S-1-5-21-*-500"
    $MyAdministrator | Set-LocalUser -Password $MyAdministratorPassword
}

"Bootstrap script ended" | Write-Host

Проверьте и отформатируйте файлы конфигураций

  1. Проверьте конфигурацию командой:

    terraform validate

    Если конфигурация является допустимой, появится сообщение:

    Success! The configuration is valid.

  2. Отформатируйте файлы конфигураций в текущем каталоге и подкаталогах:

    terraform fmt

    Результат выполнения:

    main.tf
variables.tf

Создайте ресурсы

  1. После проверки конфигурации выполните команду:

    terraform plan

    В терминале будет выведен список ресурсов с параметрами. Это проверочный этап: ресурсы не будут созданы. Если в конфигурации есть ошибки, Terraform на них укажет.

    Внимание

    Все созданные с помощью Terraform ресурсы тарифицируются. Внимательно проверьте план.

  2. Чтобы создать ресурсы выполните команду:

    terraform apply

  3. Подтвердите создание ресурсов: введите в терминал слово yes и нажмите Enter.

    Terraform создаст все требуемые ресурсы, а в терминале будут указаны IP-адреса созданных ВМ. Проверить появление ресурсов и их настройки можно в консоли управления.

Удалите ресурсы

Чтобы удалить ресурсы, созданные с помощью Terraform:

  1. Выполните команду:

    terraform destroy

    После выполнения команды в терминал будет выведен список удаляемых ресурсов.

  2. Для подтверждения удаления введите слово yes и нажмите Enter.

В этой статье: