Создание Redis-кластера

Если у вас еще нет интерфейса командной строки Yandex Cloud, установите и инициализируйте его.

По умолчанию используется каталог, указанный в профиле CLI. Вы можете указать другой каталог с помощью параметра --folder-name или --folder-id.

Чтобы создать кластер:

1. Проверьте, есть ли в каталоге подсети для хостов кластера:

   yc vpc subnet list
   

   Если ни одной подсети в каталоге нет, создайте нужные подсети в сервисе VPC.

2. Посмотрите описание команды CLI для создания кластера:

   yc managed-redis cluster create --help
   

3. При создании кластера с помощью CLI нельзя напрямую указать тип хоста и объем оперативной памяти. Вместо этого выберите подходящий класс хостов. Чтобы просмотреть доступные классы хостов, выполните команду:

   yc managed-redis resource-preset list
   

4. Укажите параметры кластера в команде создания (в примере приведены не все флаги):

   yc managed-redis cluster create \
     --name <имя кластера> \
     --environment <окружение, prestable или production> \
     --network-name <имя сети> \
     --host zone-id=<зона доступности>,subnet-id=<идентификатор подсети> \
     --security-group-ids <список идентификаторов групп безопасности> \
     --enable-tls \
     --resource-preset <класс хоста> \
     --disk-size <размер хранилища в гигабайтах> \
     --password=<пароль пользователя> \
     --backup-window-start <время начала резервного копирования в формате ЧЧ:ММ:СС>
     --deletion-protection=<защита от удаления кластера: true или false>
   

   Идентификатор подсети subnet-id необходимо указывать, если в выбранной зоне доступности создано 2 и больше подсетей.

   Включенная защита от удаления кластера не помешает подключиться вручную и удалить содержимое базы данных.

Terraform позволяет быстро создать облачную инфраструктуру в Yandex Cloud и управлять ею с помощью файлов конфигураций. В файлах конфигураций хранится описание инфраструктуры на языке HCL (HashiCorp Configuration Language). Terraform и его провайдеры распространяются под лицензией Mozilla Public License.

Подробную информацию о ресурсах провайдера смотрите в документации на сайте Terraform или в зеркале.

При изменении файлов конфигураций Terraform автоматически определяет, какая часть вашей конфигурации уже развернута, что следует добавить или удалить.

Если у вас еще нет Terraform, установите его и настройте провайдер.

Чтобы создать кластер:

1. Опишите в конфигурационном файле параметры ресурсов, которые необходимо создать:

   • Кластер базы данных — описание кластера и его хостов. При необходимости здесь же можно задать настройки СУБД.

   • Сеть — описание облачной сети, в которой будет расположен кластер. Если подходящая сеть у вас уже есть, описывать ее повторно не нужно.

   • Подсети — описание подсетей, к которым будут подключены хосты кластера. Если подходящие подсети у вас уже есть, описывать их повторно не нужно.

   Пример структуры конфигурационного файла для создания кластера с поддержкой SSL:

   terraform {
     required_providers {
       yandex = {
         source = "yandex-cloud/yandex"
       }
     }
   }
   
   provider "yandex" {
     token     = "<OAuth или статический ключ сервисного аккаунта>"
     cloud_id  = "<идентификатор облака>"
     folder_id = "<идентификатор каталога>"
     zone      = "<зона доступности>"
   }
   
   resource "yandex_mdb_redis_cluster" "<имя кластера>" {
     name                = "<имя кластера>"
     environment         = "<окружение: PRESTABLE или PRODUCTION>"
     network_id          = "<идентификатор сети>"
     security_group_ids  = [ "<идентификаторы групп безопасности>" ]
     tls_enabled         = true
     sharded             = <шардирование: true или false>
     deletion_protection = <защита от удаления кластера: true или false>
   
     config {
       password = "<пароль>"
       version  = "<версия Redis>"
     }
   
     resources {
       resource_preset_id = "<класс хоста>"
       disk_type_id       = "<тип хранилища>"
       disk_size          = <размер хранилища в гигабайтах>
     }
   
     host {
       zone      = "<зона доступности>"
       subnet_id = "<идентификатор подсети>"
     }
   }
   
   resource "yandex_vpc_network" "<имя сети>" { name = "<имя сети>" }
   
   resource "yandex_vpc_subnet" "<имя подсети>" {
     name           = "<имя подсети>"
     zone           = "<зона доступности>"
     network_id     = "<идентификатор сети>"
     v4_cidr_blocks = ["<диапазон>"]
   }
   

   Включенная защита от удаления кластера не помешает подключиться вручную и удалить содержимое базы данных.

   1. Чтобы настроить время технического обслуживания (в т. ч. для выключенных кластеров), добавьте к описанию кластера блок maintenance_window:

      resource "yandex_mdb_redis_cluster" "<имя кластера>" {
        ...
        maintenance_window {
          type = <тип технического обслуживания: ANYTIME или WEEKLY>
          day  = <день недели для типа WEEKLY>
          hour = <час дня для типа WEEKLY>
        }
        ...
      }
      

      Где:

      • type — тип технического обслуживания:
        • ANYTIME — в любое время.
        • WEEKLY — по расписанию.
      • day — день недели для типа WEEKLY в формате DDD. Например, MON.
      • hour — час дня по UTC для типа WEEKLY в формате HH. Например, 21.

   Более подробную информацию о ресурсах, которые вы можете создать с помощью Terraform, см. в документации провайдера

2. Проверьте корректность настроек.

   1. В командной строке перейдите в каталог, в котором расположены актуальные конфигурационные файлы Terraform с планом инфраструктуры.

   2. Выполните команду:

      terraform validate
      

      Если в файлах конфигурации есть ошибки, Terraform на них укажет.

3. Создайте кластер.

   1. Выполните команду для просмотра планируемых изменений:

      terraform plan
      

      Если конфигурации ресурсов описаны верно, в терминале отобразится список изменяемых ресурсов и их параметров. Это проверочный этап: ресурсы не будут изменены.

   2. Если вас устраивают планируемые изменения, внесите их:

      1. Выполните команду:

         terraform apply
         

      2. Подтвердите изменение ресурсов.

      3. Дождитесь завершения операции.

   После этого в указанном каталоге будут созданы все требуемые ресурсы, а в терминале отобразятся IP-адреса виртуальных машин. Проверить появление ресурсов и их настройки можно в консоли управления.

Воспользуйтесь методом API create и передайте в запросе:

• Идентификатор каталога, в котором должен быть размещен кластер, в параметре folderId.
• Имя кластера в параметре name.
• Идентификаторы групп безопасности в параметре securityGroupIds.
• Флаг tlsEnabled=true для создания кластера с поддержкой шифрованных SSL-соединений (для версии Redis 6.0 или старше).

Допустим, нужно создать Redis-кластер и сеть для него со следующими характеристиками:

• Имя myredis.
• Версия 6.0.
• Окружение — PRODUCTION.
• Облако с идентификатором b1gq90dgh25bebiu75o.
• Каталог с идентификатором b1gia87mbaomkfvsleds.
• Новая сеть mynet.
• Один хост класса s2.micro в новой подсети mysubnet, в зоне доступности ru-central1-c. Подсеть mysubnet будет иметь диапазон 10.5.0.0/24.
• Новая группа безопасности redis-sg, разрешающая подключения через порт 6380 с любых адресов подсети mysubnet.
• С поддержкой SSL-соединений.
• Хранилище на сетевых SSD-дисках (network-ssd) объемом 16 ГБ.
• Пароль user1user1.
• С защитой от случайного удаления кластера.

Конфигурационный файл для такого кластера выглядит так:

terraform {
  required_providers {
    yandex = {
      source = "yandex-cloud/yandex"
    }
  }
}

provider "yandex" {
  token     = "<OAuth или статический ключ сервисного аккаунта>"
  cloud_id  = "b1gq90dgh25bebiu75o"
  folder_id = "b1gia87mbaomkfvsleds"
  zone      = "ru-central1-c"
}

resource "yandex_mdb_redis_cluster" "myredis" {
  name                = "myredis"
  environment         = "PRODUCTION"
  network_id          = yandex_vpc_network.mynet.id
  security_group_ids  = [ yandex_vpc_security_group.redis-sg.id ]
  tls_enabled         = true
  deletion_protection = true

  config {
    password = "user1user1"
    version  = "6.0"
  }

  resources {
    resource_preset_id = "s2.micro"
    disk_type_id       = "network-ssd"
    disk_size          = 16
  }

  host {
    zone      = "ru-central1-c"
    subnet_id = yandex_vpc_subnet.mysubnet.id
  }
}

resource "yandex_vpc_network" "mynet" { name = "mynet" }

resource "yandex_vpc_security_group" "redis-sg" {
  name       = "redis-sg"
  network_id = yandex_vpc_network.mynet.id

  ingress {
    description    = "Redis"
    port           = 6380
    protocol       = "TCP"
    v4_cidr_blocks = ["10.5.0.0/24"]
  }

  egress {
    description    = "Redis"
    port           = 6380
    protocol       = "TCP"
    v4_cidr_blocks = ["10.5.0.0/24"]
  }
}

resource "yandex_vpc_subnet" "mysubnet" {
  name           = "mysubnet"
  zone           = "ru-central1-c"
  network_id     = yandex_vpc_network.mynet.id
  v4_cidr_blocks = ["10.5.0.0/24"]
}