Создание PostgreSQL-кластера

Если у вас еще нет интерфейса командной строки Yandex.Cloud, установите и инициализируйте его.

По умолчанию используется каталог, указанный в профиле CLI. Вы можете указать другой каталог с помощью параметра --folder-name или --folder-id.

Чтобы создать кластер:

1. Проверьте, есть ли в каталоге подсети для хостов кластера:

   $ yc vpc subnet list
   

   Если ни одной подсети в каталоге нет, создайте нужные подсети в сервисе VPC.

2. Посмотрите описание команды CLI для создания кластера:

   $ yc managed-postgresql cluster create --help
   

3. Укажите параметры кластера в команде создания (в примере приведены не все параметры):

   $ yc managed-postgresql cluster create \
      --name <имя кластера> \
      --environment <окружение, prestable или production> \
      --network-name <имя сети> \
      --host zone-id=<зона доступности>,subnet-id=<идентификатор подсети> \
      --resource-preset <класс хоста> \
      --user name=<имя пользователя>,password=<пароль пользователя> \
      --database name=<имя базы данных>,owner=<имя владельца базы данных> \
      --disk-size <размер хранилища в гигабайтах>
   

   Идентификатор подсети subnet-id необходимо указывать, если в выбранной зоне доступности создано 2 и больше подсетей.

Terraform позволяет быстро создать облачную инфраструктуру в Yandex.Cloud. Состав инфраструктуры определяется с помощью конфигурационных файлов, в которых указываются требуемые облачные ресурсы и их параметры.

Если у вас ещё нет Terraform, установите его и настройте провайдер.

Чтобы создать кластер:

1. Опишите в конфигурационном файле параметры ресурсов, которые необходимо создать:

   • Кластер базы данных — описание кластера и его хостов.
   • Сеть — описание облачной сети, в которой будет расположен кластер. Если подходящая сеть у вас уже есть, описывать ее повторно не нужно.
   • Подсети — описание подсетей, к которым будут подключены хосты кластера. Если подходящие подсети у вас уже есть, описывать их повторно не нужно.

   Пример структуры конфигурационного файла:

   resource "yandex_mdb_postgresql_cluster" "<имя кластера>" {
     name        = "<имя кластера>"
     environment = "<окружение, PRESTABLE или PRODUCTION>"
     network_id  = "<идентификатор сети>"
     
     config {
       version = "<версия PostgreSQL: 10, 10-1с, 11 или 12>"
       resources {
         resource_preset_id = "<класс хоста>"
         disk_type_id       = "<тип хранилища>"
         disk_size          = "<размер хранилища в гигабайтах>"
       }
     }
       
     database {
       name  = "<имя базы данных>"
       owner = "<имя владельца базы данных>"
     }
   
     user {
       name     = "<имя пользователя>"
       password = "<пароль пользователя>"
       permission {
         database_name = "<имя базы данных>"
       }
     }
   
     host {
       zone      = "<зона доступности>"
       subnet_id = "<идентификатор подсети>"
     }
   }
     
   resource "yandex_vpc_network" "<имя сети>" { name = "<имя сети>" }
     
   resource "yandex_vpc_subnet" "<имя подсети>" {
     name           = "<имя подсети>"
     zone           = "<зона доступности>"
     network_id     = "<идентификатор сети>"
     v4_cidr_blocks = ["<диапазон>"]
   }
   

   Более подробную информацию о ресурсах, которые вы можете создать с помощью Terraform, см. в документации провайдера.

2. Проверьте корректность конфигурационных файлов.

   1. В командной строке перейдите в каталог, в котором вы создали конфигурационный файл.

   2. Выполните проверку с помощью команды:

      terraform plan
      

   Если конфигурация описана верно, в терминале отобразится список создаваемых ресурсов и их параметров. Если в конфигурации есть ошибки, Terraform на них укажет. Это проверочный этап: ресурсы не будут созданы.

3. Создайте кластер.

   1. Если в конфигурации нет ошибок, выполните команду:

      terraform apply
      

   2. Подтвердите создание ресурсов.

   После этого в указанном каталоге будут созданы все требуемые ресурсы, а в терминале отобразятся IP-адреса виртуальных машин. Проверить появление ресурсов и их настройки можно в консоли управления.

Допустим, нужно создать PostgreSQL-кластер и сеть для него со следующими характеристиками:

• С именем mypg.
• Версии 12.
• В окружении PRESTABLE.
• В облаке с идентификатором b1gq90dgh25иuebiu75o.
• В каталоге myfolder.
• В новой сети mynet.
• С одним хостом класса s2.micro в новой подсети mysubnet, в зоне доступности ru-central1-c. Подсеть mysubnet будет иметь диапазон 10.5.0.0/24.
• С быстрым сетевым хранилищем (network-ssd) объемом 20 ГБ.
• С одним пользователем (user1), с паролем user1user1.
• С одной базой данных db1, принадлежащей пользователю user1.

Конфигурационный файл для такого кластера выглядит так:

provider "yandex" {
  token     = "<OAuth или статический ключ сервисного аккаунта>"
  cloud_id  = "b1gq90dgh25иuebiu75o"
  folder_id = "${data.yandex_resourcemanager_folder.myfolder.id}"
  zone      = "ru-central1-c"
}

resource "yandex_mdb_postgresql_cluster" "mypg" {
  name        = "mypg"
  environment = "PRESTABLE"
  network_id  = "${yandex_vpc_network.mynet.id}"

  config {
    version = 12
    resources {
      resource_preset_id = "s2.micro"
      disk_type_id       = "network-ssd"
      disk_size          = 20
    }
  }

  database {
    name  = "db1"
    owner = "user1"
  }

  user {
    name     = "user1"
    password = "user1user1"
    permission {
      database_name = "db1"
    }
  }

  host {
    zone      = "ru-central1-c"
    subnet_id = "${yandex_vpc_subnet.mysubnet.id}"
  }
}

resource "yandex_vpc_network" "mynet" {  name = "mynet" }

resource "yandex_vpc_subnet" "mysubnet" {
  name           = "mysubnet"
  zone           = "ru-central1-c"
  network_id     = "${yandex_vpc_network.mynet.id}"
  v4_cidr_blocks = ["10.5.0.0/24"]
}