Создание MySQL-кластера

Если у вас еще нет интерфейса командной строки Yandex Cloud, установите и инициализируйте его.

По умолчанию используется каталог, указанный в профиле CLI. Вы можете указать другой каталог с помощью параметра --folder-name или --folder-id.

Чтобы создать кластер:

1. Проверьте, есть ли в каталоге подсети для хостов кластера:

   $ yc vpc subnet list
   

   Если ни одной подсети в каталоге нет, создайте нужные подсети в сервисе VPC.

2. Посмотрите описание команды CLI для создания кластера:

   $ yc managed-mysql cluster create --help
   

3. Укажите параметры кластера в команде создания:

   yc managed-mysql cluster create \
     --name=<имя кластера> \
     --environment <окружение, prestable или production> \
     --network-name <имя сети> \
     --host zone-id=<зона доступности>,subnet-id=<идентификатор подсети> \
     --mysql-version <версия MySQL: 5.7 или 8.0> \
     --resource-preset <класс хоста> \
     --user name=<имя пользователя>,password=<пароль пользователя> \
     --database name=<имя базы данных> \
     --disk-size <размер хранилища в гигабайтах> \
     --disk-type <network-hdd | network-ssd | local-ssd | network-ssd-nonreplicated> \
     --security-group-ids <список идентификаторов групп безопасности> \
     --deletion-protection=<защита от удаления кластера: true или fasle>
   

   Идентификатор подсети subnet-id необходимо указывать, если в выбранной зоне доступности создано 2 и больше подсетей.

   Включенная защита от удаления кластера не помешает подключиться вручную и удалить содержимое базы данных.

   При необходимости задайте настройки СУБД.

Terraform позволяет быстро создать облачную инфраструктуру в Yandex Cloud и управлять ею с помощью файлов конфигураций. В файлах конфигураций хранится описание инфраструктуры на языке HCL (HashiCorp Configuration Language). Terraform и его провайдеры распространяются под лицензией Mozilla Public License.

Подробную информацию о ресурсах провайдера смотрите в документации на сайте Terraform или в зеркале.

При изменении файлов конфигураций Terraform автоматически определяет, какая часть вашей конфигурации уже развернута, что следует добавить или удалить.

Если у вас еще нет Terraform, установите его и настройте провайдер.

Чтобы создать кластер:

1. Опишите в конфигурационном файле параметры ресурсов, которые необходимо создать:

   • Кластер базы данных — описание кластера и его хостов.

   • Сеть — описание облачной сети, в которой будет расположен кластер. Если подходящая сеть у вас уже есть, описывать ее повторно не нужно.

   • Подсети — описание подсетей, к которым будут подключены хосты кластера. Если подходящие подсети у вас уже есть, описывать их повторно не нужно.

   Пример структуры конфигурационного файла:

   terraform {
     required_providers {
       yandex = {
         source = "yandex-cloud/yandex"
       }
     }
   }
   
   provider "yandex" {
     token     = "<OAuth или статический ключ сервисного аккаунта>"
     cloud_id  = "<идентификатор облака>"
     folder_id = "<идентификатор каталога>"
     zone      = "<зона доступности>"
   }
   
   resource "yandex_mdb_mysql_cluster" "<имя кластера>" {
     name                = "<имя кластера>"
     environment         = "<окружение, PRESTABLE или PRODUCTION>"
     network_id          = "<идентификатор сети>"
     version             = "<версия MySQL: 5.7 или 8.0>"
     security_group_ids  = [ "<список групп безопасности>" ]
     deletion_protection = <защита от удаления кластера: true или false>
   
     resources {
       resource_preset_id = "<класс хоста>"
       disk_type_id       = "<тип хранилища>"
       disk_size          = "<размер хранилища в гигабайтах>"
     }
   
     database {
       name = "<имя базы данных>"
     }
   
     user {
       name     = "<имя пользователя>"
       password = "<пароль пользователя>"
       permission {
         database_name = "<имя базы данных>"
         roles         = ["ALL"]
       }
     }
   
     host {
       zone      = "<зона доступности>"
       subnet_id = "<идентификатор подсети>"
     }
   }
   
   resource "yandex_vpc_network" "<имя сети>" { name = "<имя сети>" }
   
   resource "yandex_vpc_subnet" "<имя подсети>" {
     name           = "<имя подсети>"
     zone           = "<зона доступности>"
     network_id     = "<идентификатор сети>"
     v4_cidr_blocks = ["<диапазон>"]
   }
   

   Включенная защита от удаления кластера не помешает подключиться вручную и удалить содержимое базы данных.

   1. Чтобы настроить время технического обслуживания (в т. ч. для выключенных кластеров), добавьте к описанию кластера блок maintenance_window:

      resource "yandex_mdb_mysql_cluster" "<имя кластера>" {
        ...
        maintenance_window {
          type = <тип технического обслуживания: ANYTIME или WEEKLY>
          day  = <день недели для типа WEEKLY>
          hour = <час дня для типа WEEKLY>
        }
        ...
      }
      

      Где:

      • type — тип технического обслуживания:
        • ANYTIME — в любое время.
        • WEEKLY — по расписанию.
      • day — день недели для типа WEEKLY в формате DDD. Например, MON.
      • hour — час дня по UTC для типа WEEKLY в формате HH. Например, 21.

   Более подробную информацию о ресурсах, которые вы можете создать с помощью Terraform, см. в документации провайдера.

2. Проверьте корректность конфигурационных файлов.

   1. В командной строке перейдите в каталог, в котором создан конфигурационный файл.

   2. Выполните проверку с помощью команды:

      terraform plan
      

   Если конфигурация описана верно, в терминале отобразится список создаваемых ресурсов и их параметров. Если в конфигурации есть ошибки, Terraform на них укажет. Это проверочный этап: ресурсы не будут созданы.

3. Создайте кластер.

   1. Если в конфигурации нет ошибок, выполните команду:

      terraform apply
      

   2. Подтвердите создание ресурсов.

   После этого в указанном каталоге будут созданы все требуемые ресурсы, а в терминале отобразятся IP-адреса виртуальных машин. Проверить появление ресурсов и их настройки можно в консоли управления.

   Ограничения по времени

   Провайдер Terraform ограничивает время на выполнение операций с кластером Managed Service for MySQL:

   • создание кластера, в том числе путем восстановления из резервной копии, — 15 минут;
   • изменение кластера — 60 минут;
   • удаление кластера — 15 минут.

   Операции, длящиеся дольше указанного времени, прерываются.

   Как изменить эти ограничения?

   Добавьте к описанию кластера блок timeouts, например:

   resource "yandex_mdb_mysql_cluster" "<имя кластера>" {
     ...
     timeouts {
       create = "1h30m" # Полтора часа
       update = "2h"    # 2 часа
       delete = "30m"   # 30 минут
     }
   }
   

Воспользуйтесь методом API create и передайте в запросе:

• Идентификатор каталога, в котором должен быть размещен кластер, в параметре folderId.
• Имя кластера в параметре name. Имя кластера должно быть уникальным в рамках каталога.
• Окружение кластера в параметре environment.
• Конфигурацию кластера в параметре configSpec.
• Конфигурацию баз данных в одном или нескольких параметрах databaseSpecs.
• Настройки пользователей в одном или нескольких параметрах userSpecs.
• Конфигурацию хостов кластера в одном или нескольких параметрах hostSpecs.
• Идентификатор сети в параметре networkId.
• Идентификаторы групп безопасности в параметре securityGroupIds.

Чтобы разрешить доступ к кластеру из сервиса Yandex Data Transfer в Serverless-режиме, передайте значение true для параметра configSpec.access.dataTransfer.

Это позволит через специальную сеть подключаться к Yandex Data Transfer, запущенному в Kubernetes. В результате будут быстрее выполняться, например, запуск и деактивация трансфера.

Допустим, нужно создать MySQL-кластер и сеть для него со следующими характеристиками:

• С именем my-mysql.
• Версии 8.0.
• В окружении PRESTABLE.
• В облаке с идентификатором b1gq90dgh25bebiu75o.
• В каталоге с идентификатором b1gia87mbaomkfvsleds.
• В новой сети mynet.
• С одним хостом класса s2.micro в новой подсети mysubnet, в зоне доступности ru-central1-a. Подсеть mysubnet будет иметь диапазон 10.5.0.0/24.
• В новой группе безопасности mysql-sg, разрешающей подключение к кластеру из интернета через порт 3306.
• С хранилищем на сетевых SSD-дисках (network-ssd) объемом 20 ГБ.
• С одним пользователем (user1), с паролем user1user1.
• С одной базой данных db1, в которой пользователь user1 имеет полные права (эквивалент GRANT ALL PRIVILEGES on db1.*).
• С защитой от случайного удаления кластера.

Конфигурационный файл для такого кластера выглядит так:

terraform {
  required_providers {
    yandex = {
      source = "yandex-cloud/yandex"
    }
  }
}

provider "yandex" {
  token     = "<OAuth или статический ключ сервисного аккаунта>"
  cloud_id  = "b1gq90dgh25bebiu75o"
  folder_id = "b1gia87mbaomkfvsleds"
  zone      = "ru-central1-a"
}

resource "yandex_mdb_mysql_cluster" "my-mysql" {
  name                = "my-mysql"
  environment         = "PRESTABLE"
  network_id          = yandex_vpc_network.mynet.id
  version             = "8.0"
  security_group_ids  = [ yandex_vpc_security_group.mysql-sg.id ]
  deletion_protection = true

  resources {
    resource_preset_id = "s2.micro"
    disk_type_id       = "network-ssd"
    disk_size          = 20
  }

  database {
    name = "db1"
  }

  user {
    name     = "user1"
    password = "user1user1"
    permission {
      database_name = "db1"
      roles         = ["ALL"]
    }
  }

  host {
    zone      = "ru-central1-a"
    subnet_id = yandex_vpc_subnet.mysubnet.id
  }
}

resource "yandex_vpc_network" "mynet" {
  name = "mynet"
}

resource "yandex_vpc_security_group" "mysql-sg" {
  name       = "mysql-sg"
  network_id = yandex_vpc_network.mynet.id

  ingress {
    description    = "MySQL"
    port           = 3306
    protocol       = "TCP"
    v4_cidr_blocks = [ "0.0.0.0/0" ]
  }
}

resource "yandex_vpc_subnet" "mysubnet" {
  name           = "mysubnet"
  zone           = "ru-central1-a"
  network_id     = yandex_vpc_network.mynet.id
  v4_cidr_blocks = ["10.5.0.0/24"]
}