Создание MongoDB-кластера

Если у вас еще нет интерфейса командной строки Yandex.Cloud, установите и инициализируйте его.

По умолчанию используется каталог, указанный в профиле CLI. Вы можете указать другой каталог с помощью параметра --folder-name или --folder-id.

Чтобы создать кластер:

1. Проверьте, есть ли в каталоге подсети для хостов кластера:

   $ yc vpc subnet list
   

   Если ни одной подсети в каталоге нет, создайте нужные подсети в сервисе VPC.

2. Посмотрите описание команды CLI для создания кластера:

   $ yc managed-mongodb cluster create --help
   

3. Укажите параметры кластера в команде создания (в примере приведены только обязательные флаги):

   $ yc managed-mongodb cluster create \
      --name <имя кластера> \
      --environment=<окружение, prestable или production> \
      --network-name <имя сети> \
      --host zone-id=<зона доступности>,subnet-id=<идентификатор подсети> \
      --mongod-resource-preset <класс хоста> \
      --user name=<имя пользователя>,password=<пароль пользователя> \
      --database name=<имя базы данных> \
      --mongod-disk-type <network-hdd | network-ssd | local-ssd> \
      --mongod-disk-size <размер хранилища в гигабайтах>
   

   Идентификатор подсети subnet-id необходимо указывать, если в выбранной зоне доступности создано 2 и больше подсетей.

Terraform позволяет быстро создать облачную инфраструктуру в Yandex.Cloud и управлять ей с помощью файлов конфигураций. В файлах конфигураций хранится описание инфраструктуры на языке HCL (HashiCorp Configuration Language).

При изменении файлов конфигураций Terraform автоматически определяет, какая часть вашей конфигурации уже развернута, что следует добавить или удалить.

Если у вас еще нет Terraform, установите его и настройте провайдер.

Чтобы создать кластер:

1. Опишите в конфигурационном файле параметры ресурсов, которые необходимо создать:

   • Кластер базы данных — описание кластера и его хостов.
   • Сеть — описание облачной сети, в которой будет расположен кластер. Если подходящая сеть у вас уже есть, описывать ее повторно не нужно.
   • Подсети — описание подсетей, к которым будут подключены хосты кластера. Если подходящие подсети у вас уже есть, описывать их повторно не нужно.

   Пример структуры конфигурационного файла:

   terraform {
     required_providers {
       yandex = {
         source = "yandex-cloud/yandex"
       }
     }
   }
   
   provider "yandex" {
     token     = "<OAuth или статический ключ сервисного аккаунта>"
     cloud_id  = "<идентификатор облака>"
     folder_id = "<идентификатор каталога>"
     zone      = "<зона доступности>"
   }
   
   resource "yandex_mdb_mongodb_cluster" "<имя кластера>" {
     name               = "<имя кластера>"
     environment        = "<окружение: PRESTABLE или PRODUCTION>"
     network_id         = "<идентификатор сети>"
     security_group_ids = [ "<список групп безопасности>" ]
   
     cluster_config {
       version = "<версия MongoDB: 4.0, 4.2 или 4.4>"
     }
   
     database {
       name = "<имя базы данных>"
     }
   
     user {
       name     = "<имя пользователя>"
       password = "<пароль пользователя>"
       permission {
         database_name = "<имя базы данных>"
         roles         = [ "<список ролей пользователя>" ]
       }
     }
   
     resources {
       resource_preset_id = "<класс хоста>"
       disk_type_id       = "<тип хранилища>"
       disk_size          = <размер хранилища, ГБ>
     }
   
     host {
       zone_id   = "<зона доступности>"
       subnet_id = "<идентификатор подсети>"
     }
   }
   
   resource "yandex_vpc_network" "<имя сети>" { name = "<имя сети>" }
   
   resource "yandex_vpc_subnet" "<имя подсети>" {
     name           = "<имя подсети>"
     zone           = "<зона доступности>"
     network_id     = "<идентификатор сети>"
     v4_cidr_blocks = ["<диапазон>"]
   }
   

   Более подробную информацию о ресурсах, которые вы можете создать с помощью Terraform, см. в документации провайдера.

2. Проверьте корректность настроек.

   1. В командной строке перейдите в каталог, в котором вы создали конфигурационный файл.

   2. Выполните проверку с помощью команды:

      terraform plan
      

   Если конфигурация описана верно, в терминале отобразится список изменяемых ресурсов и их параметров. Если в конфигурации есть ошибки, Terraform на них укажет. Это проверочный этап: ресурсы не будут изменены.

3. Создайте кластер.

   1. Если в конфигурации нет ошибок, выполните команду:

      terraform apply
      

   2. Подтвердите изменение ресурсов.

   После этого в указанном каталоге будут созданы все требуемые ресурсы, а в терминале отобразятся IP-адреса виртуальных машин. Проверить появление ресурсов и их настройки можно в консоли управления.

Допустим, нужно создать MongoDB-кластер и сеть для него со следующими характеристиками:

• С именем mymg.
• Версии 4.4.
• В окружении PRODUCTION.
• В облаке с идентификатором b1gq90dgh25bebiu75o.
• В каталоге с идентификатором b1gia87mbaomkfvsleds.
• В новой сети mynet.
• С одним хостом класса s2.micro в новой подсети mysubnet, в зоне доступности ru-central1-c. Подсеть mysubnet будет иметь диапазон 10.5.0.0/24.
• В новой группе безопасности mymg-sg, разрешающей TCP-подключения к кластеру из интернета через порт 27018.
• С быстрым сетевым хранилищем (network-ssd) объемом 20 ГБ.
• С одним пользователем, user1, с паролем user1user1.
• С одной базой данных, db1.

Конфигурационный файл для такого кластера выглядит так:

terraform {
  required_providers {
    yandex = {
      source = "yandex-cloud/yandex"
    }
  }
}

provider "yandex" {
  token     = "<OAuth или статический ключ сервисного аккаунта>"
  cloud_id  = "b1gq90dgh25bebiu75o"
  folder_id = "b1gia87mbaomkfvsleds"
  zone      = "ru-central1-c"
}

resource "yandex_mdb_mongodb_cluster" "mymg" {
  name               = "mymg"
  environment        = "PRODUCTION"
  network_id         = yandex_vpc_network.mynet.id
  security_group_ids = [ yandex_vpc_security_group.mymg-sg.id ]

  cluster_config {
    version = "4.4"
  }

  database {
    name = "db1"
  }

  user {
    name     = "user1"
    password = "user1user1"
    permission {
      database_name = "db1"
    }
  }

  resources {
    resource_preset_id = "s2.micro"
    disk_type_id       = "network-ssd"
    disk_size          = 20
  }

  host {
    zone_id   = "ru-central1-c"
    subnet_id = yandex_vpc_subnet.mysubnet.id
  }
}

resource "yandex_vpc_network" "mynet" {
  name = "mynet"
}

resource "yandex_vpc_security_group" "mymg-sg" {
  name       = "mymg-sg"
  network_id = yandex_vpc_network.mynet.id

  ingress {
    description    = "MongoDB"
    port           = 27018
    protocol       = "TCP"
    v4_cidr_blocks = [ "0.0.0.0/0" ]
  }
}

resource "yandex_vpc_subnet" "mysubnet" {
  name           = "mysubnet"
  zone           = "ru-central1-c"
  network_id     = yandex_vpc_network.mynet.id
  v4_cidr_blocks = ["10.5.0.0/24"]
}